[es] - Euro 2008-excell, pomoć

Jelisic Sasa
serviser racunara,Panta rei

Član broj: 178771
Poruke: 5
*.bl.pttrs.net.

Profil

Euro 2008-excell, pomoć

^{05.06.2008. u 00:20 - pre 193 meseci}

Ovo što hoću da napravim je naravno lakše bilo uraditi „pješke” ali mi je palo na pamet da vidim da li mogu to izvesti automatski,vježbanje vijuga.Radi se o sljedećem: nas nekoliko tipujemo za Euro 2008 rezultate svih utakmica. Ko pogodi pobjednika ili da će biti neriješeno dobija 1 poen, a ko pogodi tačan rezultat dobija 3 poena. Da li se to može u Excell-u napravti da ja po završetku utakmice samo upišem rezultat a da mi program odmah upiše koliko je ko dobio poena za tu utakmicu. Ja sam pokušavao ovako: ćelija G3 je broj pogodaka „domaćeg” tima;H3 je nebitan, estetike radi pišem crticu;I3 je broj pogodaka „gostujćeg” tima; J3 je moje tipovanje za „domaći”, a L3 za „gostujući” tim pa sam kucao:
IF((G3>I3)*AND(J3>L3))*OR((G3<I3)*AND(J3<L3));(G3`=`I3)*AND(J3`=`L3)1;0
i razne druge pokušaje ali nije išlo.
Može li se to napraviti i kako. Hvala.
P.S. Kao što se vidi nisam još ni došao do onoga da za tačan rezultat daje 3 boda.

Odgovor na temu

timmy
Jovan Timotijevic

Moderator
Član broj: 37087
Poruke: 634

Sajt: www.e-tim.net

+89 Profil

Re: Euro 2008-excell, pomoć

^{05.06.2008. u 11:38 - pre 193 meseci}

Evo kako bi moglo da se resi
Ako su u

A2 HomeGoal, C2 AwayGoal kao i
E2 HomeGoalTip, G2 AwayGoalTip

Code:

=IF(AND(A2=E2,C2=G2),3,IF(IF(A2>C2,1,IF(A2=C2,0,2))=IF(E2>G2,1,IF(E2=G2,0,2)),1,0))

Pozdrav

Prikačeni fajlovi

tip.gif - 8.79k

Odgovor na temu

Jelisic Sasa
serviser racunara,Panta rei

Član broj: 178771
Poruke: 5
81.94.4.*

Profil

Re: Euro 2008-excell, pomoć

^{05.06.2008. u 17:25 - pre 193 meseci}

Svaka čast!!!Radi baš onako kako sam zamišljao. Pošto sam rekao na početku da mi ovo više služi za vježbanje u Excell-u, molio bih Vas da mi malo objasnite logičku strukturu finkcije ako tako mogu reći. Nisam pretpostavljao da je to moguće odraditi bez OR komande. Ovo je bio moj pokušaj prije nego što ste vi odgovorili i nije radio, ako možete pogledati pa mi reći gdje griješim =IF(((E3=G3)*AND(H3=J3))*OR(IF((E3>G3)*AND(H3>J3),1,0)),1,0)
Još nešto, ako sada unesem sve naše tipove za sve utakmice 1.kruga program odmah dodjeljuje 1 poen tamo gdje smo tipovali neriješeno odnosno 3 poena gdje smo tipovali 0-0. Može li se to izbjeći. Hvala na trudu i pomoći i zaista vam čestitam na elegantnom rješenju

Odgovor na temu

Jelisic Sasa
serviser racunara,Panta rei

Član broj: 178771
Poruke: 5
81.94.4.*

Profil

Re: Euro 2008-excell, pomoć

^{05.06.2008. u 17:39 - pre 193 meseci}

=IF(AND(A2=E2,C2=G2),3,IF(IF(A2>C2,1,IF(A2=C2,0,2))=IF(E2>G2,1,IF(E2=G2,0,2)),1,0)).
Nisu mi jasne vrijednosti za FALSE poslije 4. i 6. IF, tj. otkud tu dvojke. Hvala.

Odgovor na temu

timmy
Jovan Timotijevic

Moderator
Član broj: 37087
Poruke: 634

Sajt: www.e-tim.net

+89 Profil

Re: Euro 2008-excell, pomoć

^{05.06.2008. u 21:32 - pre 193 meseci}

Ukoliko hoces da se broj poena dodeljuje samo kada budes imao unete rezultate utakmica,
a ne da unapred imas po 1 osvojen poen tada bi formula trebala da glasi:

Code:

=IF(COUNT(A2,C2)<2,0,IF(AND(A2=E2,C2=G2),3,IF(IF(A2>C2,1,IF(A2=C2,0,2))=IF(E2>G2,1,IF(E2=G2,0,2)),1,0)))

a deo koda za koji se pitas sta je

Code:

IF(A2>C2,1,IF(A2=C2,0,2))

sluzi da za uneti rezultat dogadjaja, za pobedu domacina uzme "1", za nereseno "0" a za pobedu gosta "2".
Dok drugi deo formule to isto radi za tvoj tip

Code:

IF(E2>G2,1,IF(E2=G2,0,2))

Onda se te dve vrednosti uporede i ako su iste dobijes 1 poen u suprotnom 0

Pozdrav

Odgovor na temu

Jelisic Sasa
serviser racunara,Panta rei

Član broj: 178771
Poruke: 5
81.94.4.*

Profil

Re: Euro 2008-excell, pomoć

^{07.06.2008. u 08:19 - pre 193 meseci}

Još jednom čestitke, i ovaj dodatak radi, on mi je jasan jedino što ja nisam znao za tu komandu "count", proučio sam i ostatak reda i sad mi je i to jasno tako da vam zahvaljujem i na objašnjenju. Pozdrav.

Odgovor na temu